内加强圈OR外加强圈
在标准规范里，外压加强圈可以设置在内部也可以设置在外部，对于内加强圈和外加强圈，规范采用的公式是一样的，在规范里，这两者并没有不同。
但是实际情况是，内外肯定是有少许差别的。如果只考虑受力问题，那么到底是外加强圈好还是内加强圈好呢？
外加强圈好的理由是：用的材料多，惯性矩大。
内加强圈好的理由是：内加强圈是受压，尺寸更小，更不容易失稳。
当加强圈都很强的时候，对于壳体的加强是基本一致的。强的加强圈和较强的加强圈都起加强作用，壳体的许用外压值是一样的。然而，疾风知劲草，板荡识忠臣，路遥知马力，日久见人心。当加强圈渐渐衰弱，壳体的许用外压值会慢慢变化，同样截面的加强圈，由于心态的变化，对母体的支持程度是不一样的。那么我们就来试试究竟是内向好还是外向好。
试验手段是采用ansys的做一个屈曲分析，计算结构的屈曲特征值，用来定性分析内外加强圈的不同。
为了一次达到试验目的，首先我们需要选择一个不那么强的加强圈。
加强圈计算不合格才是我们需要的，如果加强圈合格，内外计算得到的结果一样，那就没法比较了。
选择和SW6试算过的计算模型：筒体材料为Q345R，尺寸为1000*8 L=3000，内外加强圈均为60*10的扁钢。那么到底是内加强圈好还是外加强圈好呢？
首先计算加强圈在外侧的模型
约束施加：
两个端面上节点转成柱面坐标，限制转动和轴向位移。
施加外压1Mpa。
采用特征值法计算临界屈曲载荷，得到的变形结果，从变形波数可以得到，这是个短圆筒。
临界压力为1.82266MPa。即许用外压为1.82266MPa。一般筒体的许用外压，采用特征值法的时候，安全系数取3~4。
再计算加强圈在内侧的模型，与外侧模型约束和载荷一样。得到的失稳波形如下图，和上面的失稳波形完全一样。真是幸福的家庭有着相同的幸福，相同的短圆筒有着相同的波形。
内部加强圈的临界失稳压力为1.90028MPa。
从定性上来说，内部的加强圈临界失稳压力大于外部加强圈的临界失稳压力。那么可以初步下这么个结论：
如果只考虑受力，相同尺寸的加强圈，内加强圈效果比外加强圈效果略好。
从数值上讲，文中的例子，差距在除安全系数后，可以忽略不计。
为了朋友们能够自己验证,下面贴出外加强圈的命令流：
finish
/clear
!环境设置
/filn,Stiff
/title,Stiffring outside
*SET,D1,1000 ! 筒体内径
*SET,L1,3000 ! 筒体长度
*SET,T,8 ! 筒体厚度
L2=500
L3=2500
W1=60
T1=10
*SET,P,1 ! 施加内压值
qz=-P*D1**2/(4*T*(D1+T)) ! 筒体载荷边界，未使用
/prep7
!定义单元及材料属性
et,1,solid186 ! 实体单元
mp,ex,1,2.05e5 ! 壳体、接管与补强圈材料弹性模量
mp,prxy,1,0.30 ! 壳体与补强圈材料泊松比
cylind,D1/2,D1/2+T,,L1,,360 ! 创建1/4筒体
cylind, D1/2-w1, D1/2+T+w1,l2,l2+t1,,360
cylind, D1/2-w1, D1/2+T+w1,l3,l3+t1,,360
vovlap,all,all !Creat stiff ring
vsel,s, , , 10,12,2
vdele,all,,,1
allsel
wprota,,90,
allsel
VSBW,all
wprota,, ,90
allsel
VSBW,all
vglue,all
nummrg,all ! 对所有实体信息进行压缩
numcmp,all
!划分网格
allsel
Allsel
Lsel,s,radius,, 0.5*d1,
Lesize,all,,,16
Allsel
Lsel,s,length,,t,t1
Lesize,all,,,2
allsel
Lsel,s,radius,, D1/2+T+w1,
Lesize,all,,,16
allsel
Lsel,s,radius,, D1/2+T,
Lesize,all,,,16
Allsel
Lsel,s,length,,w1,
Lesize,all,,,8
allsel
lsel,s,,,90,94,4
lesize,all,,,16
lsel,s,,,73
lesize,all,,,64
allsel
mshape,0,3D
Vsweep,all
!划分网格完成
allsel,all
NUMMRG,NODE, , , ,LOW
vplot
!网格划分完成
wpcsys,-1,0
allsel
Asel,s,loc,z,0
Asel,a,loc,z,l1
csys,1 !转化成柱坐标系
NSLA,R,1 !选择面上的节点
NROTAT,ALL
D,ALL,,0,,,,UY
D,ALL,,0,,,,UZ !施加轴向和环向约束
allsel
CSYS,0
FINI
!屈曲特征值部分
/SOLU !进入求解
ANTYPE,STATIC !在进行屈服分析之前，ANSYS需要从静态分析提取数据
PSTRES,ON !屈服分析中采用预应力
allsel ! 全选择
csys,1 !转化成柱坐标系
asel,s,loc,x,d1/2
CSYS,0
Sfa,all,1,pres,-p
SOLVE !求解
FINISH !退出求解
/SOLU !重新进入求解模型进行屈服分析
ANTYPE,BUCKLE !屈服分析类型
BUCOPT,LANB,1 !1阶模态，子空间法
SOLVE !求解
FINISH !退出求解
/SOLU !重新进入求解展开模态
EXPASS,ON !模态展开打开
MXPAND,1 !定义需要展开的阶数
SOLVE !求解
FINISH !退出求解
/POST1 !进入通用后处理
SET,LIST !列出特征值求解结果
SET,LAST !读入感兴趣阶数模态结果
PLDISP !显示变形后图形
